Gauss Map in R^3

Joshua R. Davis, jdavis@carleton.edu, revised 2020 October 14

Cylinder

Here’s a Mathematica detail that you might not know. When you end a line in a semicolon, the output from that line is not shown to you. (The line still has its other effects, such as computing a value and storing it in a variable.)

Clear[r, x, y];
f = {r Cos[x], r Sin[x], y};
ParametricPlot3D[f /. {r -> 3}, {x, 0, 2 Pi}, {y, -1, 1}]

The un-semicoloned lines show the Jacobian of f, the composition n f, and the Jacobian of the composition.

dfdx = Simplify[Transpose[{D[f, x], D[f, y]}]];
MatrixForm[dfdx]
nf = Cross[D[f, x], D[f, y]];
nf = Simplify[nf / Norm[nf], {r > 0, 0 < x < 2 Pi, Element[y, Reals]}]
dnfdx = Simplify[Transpose[{D[nf, x], D[nf, y]}]];
MatrixForm[dnfdx]

Here we try to compute the matrix A of the differential dn with respect to the basis df/dx, df/dy, and its eigenvalues.

a = {{a11, a12}, {a21, a22}} /. Solve[
{dnfdx[[All, 1]] == a11 dfdx[[All, 1]] + a21 dfdx[[All, 2]], 
dnfdx[[All, 2]] == a12 dfdx[[All, 1]] + a22 dfdx[[All, 2]]}, 
{a11, a21, a12, a22}][[1]];
MatrixForm[a]
Eigenvalues[a]

Sphere

We have many parametrizations of the sphere, from which to choose. Let’s use spherical coordinates.

Clear[r, x, y];
f = {r Sin[x] Cos[y], r Sin[x] Sin[y], r Cos[x]};
ParametricPlot3D[f /. {r -> 3}, {x, 0, Pi}, {y, 0, 2 Pi}]

The Jacobian of f, the composition n f, and the Jacobian of the composition.

dfdx = Simplify[Transpose[{D[f, x], D[f, y]}]];
MatrixForm[dfdx]
nf = Cross[D[f, x], D[f, y]];
nf = Simplify[nf / Norm[nf], {r > 0, 0 < x < Pi, 0 < y < 2 Pi}]
dnfdx = Simplify[Transpose[{D[nf, x], D[nf, y]}]];
MatrixForm[dnfdx]

The matrix A of the differential dn with respect to the basis df/dx, df/dy, and its eigenvalues.

a = {{a11, a12}, {a21, a22}} /. Solve[
{dnfdx[[All, 1]] == a11 dfdx[[All, 1]] + a21 dfdx[[All, 2]], 
dnfdx[[All, 2]] == a12 dfdx[[All, 1]] + a22 dfdx[[All, 2]]}, 
{a11, a21, a12, a22}][[1]];
MatrixForm[a]
Eigenvalues[a]

Saddle

This surface is an example of a saddle.

Clear[x, y];
f = {x, y, x y};
ParametricPlot3D[f, {x, -1, 1}, {y, -1, 1}]

The Jacobian of f, the composition n f, and the Jacobian of the composition.

dfdx = Simplify[Transpose[{D[f, x], D[f, y]}]];
MatrixForm[dfdx]
nf = Cross[D[f, x], D[f, y]];
nf = Simplify[nf / Norm[nf], {Element[x, Reals], Element[y, Reals]}]
dnfdx = Simplify[Transpose[{D[nf, x], D[nf, y]}]];
MatrixForm[dnfdx]

The matrix A of the differential dn with respect to the basis df/dx, df/dy, and its eigenvalues.

a = {{a11, a12}, {a21, a22}} /. Solve[
{dnfdx[[All, 1]] == a11 dfdx[[All, 1]] + a21 dfdx[[All, 2]], 
dnfdx[[All, 2]] == a12 dfdx[[All, 1]] + a22 dfdx[[All, 2]]}, 
{a11, a21, a12, a22}][[1]];
MatrixForm[a]
Eigenvalues[a]

Yikes! Let’s look at what’s happening just at (x, y) = (0, 0). Here’s the matrix A, its eigenvalues, and their corresponding eigenvectors.

MatrixForm[a /. {x -> 0, y -> 0}]
Eigenvalues[a /. {x -> 0, y -> 0}]
Eigenvectors[a /. {x -> 0, y -> 0}]